Create and release product variant Dynamics 365

Code below can be used to create and release product variant in Dynamics AX 2012 & Dynamics 365 Operations.

It will work straight forwardly for AX 2012.

For Dynamics 365 operations,you need to create runable class to execute the same.

I have checked and tested that below code is working fine in dynamics 365 operations for different application but not to import data.

As all the classes and tables used below are available in Dynamics 365 operations, it should work to import as well.

Awaiting for feedback, if any!

 static void dtReleaseProductAllVariant(Args _args)  
 {  
   ecoResDistinctProductVariant    ecoResDistinctProductVariant;  
   EcoResProductVariantDimensionValue EcoResProductVariantDimensionValue;  
   RefRecId              ecoResDistinctProductVariantRecId;  
   EcoResProductReleaseManagerBase   releaseManager;  
   container              productDimensions;  
   EcoResProduct            ecoResProduct;  
   EcoResProductDimensionAttribute   prodDimensionAttribute; //fix for perticular dim, using tableid  
   //Configuration  
   EcoResProductMasterConfiguration  productMasterConfiguration;  
   EcoResConfiguration         ecoResConfiguration;  
   //Color  
   EcoResProductMasterColor      productMasterColor;  
   EcoResColor             ecoResColor;  
   //Size  
   EcoResProductMasterSize       productMasterSize;  
   EcoResSize             ecoResSize;  
   //Style  
   EcoResProductMasterStyle      productMasterStyle;  
   EcoResStyle             ecoResStyle;  
   CommaTextIo         file;  
   container          rec;  
   Dialog       d;  
   DialogField     df1, df2;  
   int64        counter = 0;  
   ;  
   d = new Dialog("Release Product Variant");  
   df1 = d.addField(ExtendedTypeStr("FilenameOpen"));  
   if (d.run())  
   {  
     file = new CommaTextIo(df1.value(), 'r');  
     file.inFieldDelimiter(';');  
     try  
     {  
       while (file.status() == IO_Status::Ok)  
       {  
         rec = file.read();  
         if(!rec)  
           break;  
           ttsBegin;  
           ecoResProduct = EcoResProduct::findByProductNumber(conPeek(rec, 1));  
           //Configuration - Start  
           ecoResConfiguration = EcoResConfiguration::findByName(conPeek(rec, 2));  
           if (!ecoResConfiguration.RecId)  
           {  
             ecoResConfiguration.Name = conPeek(rec, 2);  
             ecoResConfiguration.insert();  
           }  
           select * from productMasterConfiguration where productMasterConfiguration.Configuration == ecoResConfiguration.RecId &&  
                             productMasterConfiguration.ConfigProductMaster == ecoResProduct.RecId;  
           if(!productMasterConfiguration.RecId)  
           {  
             select * from prodDimensionAttribute where prodDimensionAttribute.DimensionTableId == tableNum(EcoResConfiguration);  
             productMasterConfiguration.Configuration              = ecoResConfiguration.RecId;  
             productMasterConfiguration.ConfigProductDimensionAttribute     = prodDimensionAttribute.RecId;  
             productMasterConfiguration.ConfigProductMaster           = ecoResProduct.RecId;  
             productMasterConfiguration.insert();  
           }  
           //Configuration - End  
           //Size - Start  
           ecoResSize = EcoResSize::findByName(conPeek(rec, 3));  
           if (!ecoResSize.RecId)  
           {  
             ecoResSize.Name = conPeek(rec, 3);  
             ecoResSize.insert();  
           }  
           select * from productMasterSize where productMasterSize.Size == ecoResSize.RecId &&  
                             productMasterSize.SizeProductMaster == ecoResProduct.RecId;  
           if(!productMasterSize.RecId)  
           {  
             select * from prodDimensionAttribute where prodDimensionAttribute.DimensionTableId == tableNum(EcoResSize);  
             productMasterSize.Size              = ecoResSize.RecId;  
             productMasterSize.SizeProductDimensionAttribute  = prodDimensionAttribute.RecId;  
             productMasterSize.SizeProductMaster        = ecoResProduct.RecId;  
             productMasterSize.insert();  
           }  
           //Size - End  
           //Color - Start  
           ecoResColor = EcoResColor::findByName(conPeek(rec, 4));  
           if (!ecoResColor.RecId)  
           {  
             ecoResColor.Name = conPeek(rec, 4);  
             ecoResColor.insert();  
           }  
           select * from productMasterColor where productMasterColor.color == ecoResColor.RecId &&  
                             productMasterColor.ColorProductMaster == ecoResProduct.RecId;  
           if(!productMasterColor.RecId)  
           {  
             select * from prodDimensionAttribute where prodDimensionAttribute.DimensionTableId == tableNum(EcoResColor);  
             productMasterColor.Color              = ecoResColor.RecId;  
             productMasterColor.ColorProductDimensionAttribute  = prodDimensionAttribute.RecId;  
             productMasterColor.ColorProductMaster        = ecoResProduct.RecId;  
             productMasterColor.insert();  
           }  
           //Color - End  
           //Style - Start  
           ecoResStyle = EcoResStyle::findByName(conPeek(rec, 5));  
           if (!ecoResStyle.RecId)  
           {  
             ecoResStyle.Name = conPeek(rec, 5);  
             ecoResStyle.insert();  
           }  
           select * from productMasterStyle where productMasterStyle.Style == ecoResStyle.RecId &&  
                             productMasterStyle.StyleProductMaster == ecoResProduct.RecId;  
           if(!productMasterStyle.RecId)  
           {  
             select * from prodDimensionAttribute where prodDimensionAttribute.DimensionTableId == tableNum(EcoResStyle);  
             productMasterStyle.Style              = ecoResStyle.RecId;  
             productMasterStyle.StyleProductDimensionAttribute  = prodDimensionAttribute.RecId;  
             productMasterStyle.StyleProductMaster        = ecoResProduct.RecId;  
             productMasterStyle.insert();  
           }  
           //Style - End  
           //Create a container to hold dimension values  
           productDimensions = EcoResProductVariantDimValue::getDimensionValuesContainer(conPeek(rec, 2),  
                                                   conPeek(rec, 3),  
                                                   conPeek(rec, 4),  
                                                   conPeek(rec, 5));  
           //Create Product search name  
           ecoResDistinctProductVariant.DisplayProductNumber = EcoResProductNumberBuilderVariant::buildFromProductNumberAndDimensions(  
                                             conPeek(rec, 1),  
                                             productDimensions);  
           //Create Product variant with Product and dimensions provided  
           ecoResDistinctProductVariantRecId = EcoResProductVariantManager::createProductVariant(ecoResProduct.RecId,  
                                             ecoResDistinctProductVariant.DisplayProductNumber,  
                                             productDimensions);  
           //Find newly created Product Variant  
           ecoResDistinctProductVariant = ecoResDistinctProductVariant::find(ecoResDistinctProductVariantRecId);  
           //Now release the Product variant  
           releaseManager = EcoResProductReleaseManagerBase::newFromProduct(ecoResDistinctProductVariant);  
           releaseManager.release();  
           counter++;  
           ttsCommit;  
         info(strFmt("%1 Product variant released successfully",conPeek(rec, 1)));  
         info(strFmt("Total %1 Product variants released successfully",counter));  
       }  
     }  
     catch  
     {  
       info(strFmt("Total %1 Product variants released successfully",counter));  
       info(strFmt("Job terminated for product %1 and config %2 Size %3 Color %4 Style %5",conPeek(rec, 1),conPeek(rec, 2),conPeek(rec, 3),conPeek(rec, 4),conPeek(rec, 5)));  
     }  
   }  
 }  

Dynamics ax administration guide

1) Deploy all Reports using Dynamics AX Power shell.

Publish-AXReport –ReportName * -id <AX Report server config name>

2) Delete label files from AOT - Dynamics AX 2012.
Solution provided in below two blogs are useful.

https://community.dynamics.com/ax/b/axilitynet/archive/2015/12/08/label-file-creation-and-language-removal

http://www.agermark.com/2014/01/how-to-delete-label-files-from-ax-2012.html

3) Scale out dynamics 365 operation On Premise installation.

https://blogs.msdn.microsoft.com/axsa/2018/06/28/how-to-scale-out-dynamics-365-for-finance-and-operations-on-premises/

4) SQL/Dynamics AX Administration.
     a. Read this post to get currently running queries, this will help to identify if any blocking.
     b. Read this post to get script for re-indexing and statics update for Dynamics AX database.
     c. Read this post to get script for SQL wait stats - Link

5) Management Reporter
    a. This link is useful to Rebuild Management Reporter Database.
    b. This link is useful to find MRDM synchronization issues due to bad records.

6) Visio diagrams
     1) Stencils Dell - Link
     2) Stencils Cisco - Link

7) Object Id conflicts, while synchronization - Link

Create simple dialog dynamics 365 Operations

Below code can be used as base to create dialog in Dynamics 365 Operations.

To Start with, create new project in either existing model or create new model and add a new Runnable class with name ppPurchDeliveryScheduleCreateDialog.

Copy code below and past into your class code area, this contains all the basic methods, which are required to override while extending RunBase class.

Modify logic of this dialog as per your requirement.

/// <summary>

/// The <c>ppPurchDeliveryScheduleCreate</c> class takes inputs from user and creates delivery schedule lines.

/// </summary>

/// <remarks>

/// Create delivery schedule lines.

/// </remarks>

public class ppPurchDeliveryScheduleCreateDialog extends RunBase

{

    // User Input fields

    DialogField     fieldNoOfLines;

    

    // Variables to store user input

    ppNumberOfLines numberOfLines;

    // pack() and unpack() methods are used to load the last value from user

    // for our simple example we are not going to use them.

    public container pack()

    {

        return conNull();

    }

    public boolean unpack(container packedClass)

    {

        return true;

    }

    // Dialog method to capture runtime user inputs for customer details

    public Object dialog()

    {

        Dialog dialog = super();

        // Set a title for dialog

        dialog.caption( 'Enter number of lines:');

        // Add a new field to Dialog

        fieldNoOfLines = dialog.addField(extendedTypeStr(ppNumberOfLines), 'No of lines:');

        return dialog;

    }

    // Retrieve values from Dialog

    public boolean getFromDialog()

    {

        numberOfLines = fieldNoOfLines.value();

        return super();

    }

    //write business logic.

    public void run()

    {

        //TODO: User numberOfLines variable to create delivery schedule.

    }

    public static void main(Args _args)

    {

        ppPurchDeliveryScheduleCreateDialog deliverySchedule = new ppPurchDeliveryScheduleCreateDialog();

        // Prompt the dialog, if user clicks in OK it returns true

        if (deliverySchedule.prompt())

        {

            deliverySchedule.run();

        }

    }

}

Basic rounding in dynamics 365

Basic rounding in dynamics 365FO/AX.

Retrieve last approver name for any workflow

Below code can be used to retrieve last approver name for any workflow activated in Dynamics AX/ 365 Finance and operations.

 static void dtGetLastApproverName(Args _args)  
 {  
    WorkflowTrackingStatusTable workflowTrackingStatus;  
    WorkflowTrackingTable workflowTrackingTable;  
    WorkflowTrackingCommentTable workflowTrackingCommentTable;  
    UserInfo userInfo;  

    select firstFast RecId, User from workflowTrackingTable  
     order by RecId desc   
     join workflowTrackingCommentTable   
    where workflowTrackingCommentTable.WorkflowTrackingTable ==   
          workflowTrackingTable.RecId  
    join UserInfo where UserInfo.id == WorkflowTrackingTable.User  
    exists join workflowTrackingStatus  
    where workflowTrackingTable.WorkflowTrackingStatusTable ==   
    workflowTrackingStatus.RecId  
    && workflowTrackingStatus.ContextRecId == _salesRecId //PurchRecID  
    && workflowTrackingStatus.ContextTableId == tableNum(SalesTable) //SalesTable  
    && workflowTrackingTable.TrackingType == WorkflowTrackingType::Approval;  

    if (workflowTrackingTable.RecId > 0)  
    {  
      info(strFmt(“%1 – %2 “,userInfo.name, workflowTrackingCommentTable.RecId));  
    }  
 }  

Move SQL Server database files

Create tempdb partitions and move to new location location.

Know existing location:
SELECT name, physical_name FROM sys.master_files WHERE database_id = DB_ID('tempdb');

Move to new location:

ALTER DATABASE tempdb MODIFY FILE ( NAME = tempdev, FILENAME = "C:\SQLDB\tempdb.mdf")
ALTER DATABASE tempdb MODIFY FILE ( NAME = templog, FILENAME = "C:\SQLDB\templog.ldf")
ALTER DATABASE tempdb MODIFY FILE ( NAME = tempdev1, FILENAME = "C:\SQLDB\tempdb1.mdf")
ALTER DATABASE tempdb MODIFY FILE ( NAME = templog1, FILENAME = "C:\SQLDB\templog1.ldf")

Note:
Also verify that SQL service account has full access to new location.

To move msdb, need to follow steps below after executing above queries.

1. Go to SQL Server configuration manager.

2. Update path on parameters.

Verify active/enabled product dimension

Below code can be used to verify active or enabled specific or all product dimensions.

 
   public static void main(Args _args)
   {
     InventTable   inventTable;  
     InventDimParm  inventDimParm;  
     ;  

     inventTable  = InventTable::find('ABC');  

     inventDimParm = InventDimParm::activeDimFlag(InventDimGroupSetup::newInventTable(inventTable));  

     if(inventDimParm.InventColorIdFlag)  
     {  
       info("Color Enabled."); 
     }  
   }